BASIC プログラム
USB ケーブルやシリアルケーブルでパソコンと接続するのが便利です。
Windows では「PC-G リンク」を用いるのが普通です。
配布サイトがいくつかあります。
Tera Term では シリアル で接続後 ファイル - ファイル送信 で送れます。
Mac では「PCG-LinkMac」等を使用できます。
その他 z88dk の examples/g800 にある send.py も使用できます。
エミュレータ g800 を用いる場合はダウンロードしたファイルを
（GitHub Gist による表示ではなく「ダウンロード」リンクから）
ドラック＆ドロップで g800 表示画面へ持っていって下さい。
（コマンドラインでオプション指定する方法もあります）
実機および g800 へ実機 ROM データを使用している場合は
TEXT - Sio - Load で読み込み、TEXT - Basic - Basic<text で BASIC へ変換します。
（ TEXT はデフォルトで F2 キー。TEXT EDITOR メニューになります）
g800 の互換 BASIC では上記の操作不要です。
あとは BASIC で RUN MODE にして RUN で実行できます。
（ BASIC はデフォルトで F1 キー。PROGRAM MODE と交互に切り替わります）
互換 BASIC インタープリタでも全プログラム正常動作を確認できています。
手入力したい場合は BASIC キーを押してモードを切り替えます。
PROGRAM MODE で入れた後、RUN MODE にして RUN で実行します。
GitHub Gist を用いて公開しているコードには MIT ライセンス の明示を行っています。
個人的に使用する場合、頭の ' は入力しなくても動作に影響はありませんが、
配布などを行う場合はライセンス上含める必要があります。
GitHub Gist ではカナの文字コードが異なっています。
ランダム画面
PC-E200・G シリーズ 等
空白 と ▋ をランダムに表示していきます。
他の機種と違いがあるのは、右下に文字を表示してもスクロールが発生しません。
また RND は 2 以上の場合、RND 6 だと 1～6 の範囲になります。
（2 未満だと 0 以上 1 未満の小数）
100 CLS
110 RANDOMIZE
120 X= RND 24-1
130 Y= RND 4-1
140 C= RND 2
150 LOCATE X,Y
160 IF C=1 PRINT CHR$ (32);
170 IF C=2 PRINT CHR$ (142);
180 GOTO 120
PC-G850 シリーズはそのままでも動作しますが、次を変えて全画面になります。
130 Y= RND 6-1
IchigoJam・IchigLatte・IchigonQuest 版や MSX 版も存在します。
ランダム画面 | イチゴジャム レシピ - IchigoJam BASIC 版
ランダム画面 2 | イチゴジャム レシピ - IchigoJam BASIC 版
ランダム画面 | イチゴジャム レシピ - IchigoLatte JavaScript 版
ランダム画面 | イチゴジャム レシピ - IchigoLatte Ruby 版
ランダム画面 | イチゴジャム レシピ - IchigonQuest 版
ランダム画面 | MSX JAPAN▉ - MSX-BASIC 版
数当て
PC-E200・G シリーズ 等
ポケコンが 0～99 をランダムで選定しているので、この数を当てます。
異なっている場合は「チイサイ」「オオキイ」を表示します。
当たった場合はプログラムが終了して「＞」を表示します。
再度行う場合は RUN して下さい。
10 RANDOMIZE
20 I=0
30 R= RND 100-1
40 I=I+1
50 PRINT "ﾀｰﾝ ";I;
60 INPUT " ｶｽﾞ(0-99)>";K
70 IF K>R PRINT "ﾁｲｻｲ":GOTO 40
80 IF R>K PRINT "ｵｵｷｲ":GOTO 40
90 END
IchigoJam BASIC 版・IchigoLatte 版もあります。
数当て | イチゴジャム レシピ - IchigoJam BASIC 版
数当て | イチゴジャム レシピ - IchigoLatte JavaScript 版
風船
PC-E200・G シリーズ 等
風船を飛ばします。
テキストで風船を表現しようとすると ● と l (英小エル) となりました。
スクロールするために、130 で PRINT した後、150 で更に PRINT しています。
100 CLS
110 R= RND 24-1
120 LOCATE R,3
130 PRINT CHR$ (236)
140 WAIT 3
150 PRINT
160 LOCATE R,3
170 PRINT "l"
180 GOTO 110
PC-G850 シリーズで上のプログラムを動作するためには次を変更します。
120 LOCATE R,5
160 LOCATE R,5
PC-G850 シリーズ
PC-G850 シリーズ版では GPRINT で風船を描き、
CALL &HBFEB で 1 行上にスクロールします。
ただ、スクロール後に下で一瞬表示されてしまうので、
スクロール直前で消しています。（160 の空白は 24 文字＝1 行分 です）
PC-G850 シリーズではテキストとグラフィックが同じ画面で線画されるので、
この方法で実現できます。ただし LINE～,R,BF よりもテキストの方が速いです。
PC-G850 シリーズは Z80 を採用している中では新しい機種である事もあり、
GPRINT であれば、BASIC でもけっこうはやく、WAIT を入れている程です。
100 CLS
110 X= RND 137-1
120 GCURSOR (X,47)
130 GPRINT "1C3E7FFF7D3A1C"
140 WAIT 3
150 LOCATE 0,0
160 PRINT " "
170 CALL &HBFEB
180 GCURSOR (X,47)
190 GPRINT "0000009966"
200 GOTO 110
160 PRINT " " の "" 内は空白 24 文字です。（1 行の文字数）
170 CALL &HBFEB は次でも同じ動作になります。
170 LOCATE 0,5:PRINT:PRINT
z88dk を用いた C 言語版もあります。PC-G850 シリーズ以外でも動作します。
balloons.c | GitHub Gist - z88dk C 言語版
MSX・IchigoJam・IchigoLatte・IchigonQuest 版もあります。
風船 | MSX JAPAN▉ - MSX 版
風船 | イチゴジャム レシピ - IchigoJam BASIC 版
風船 version 2 | イチゴジャム レシピ - IchigoLatte BASIC 版
風船 | イチゴジャム レシピ - IchigoLatte JavaScript 版
風船 | イチゴジャム レシピ - IchigoJLatte Ruby 版
風船 | イチゴジャム レシピ - IchigoJLatte Forth 版
風船 | イチゴジャム レシピ - IchigonQuest 版
ジャンケンポン！
PC-E200・G シリーズ 等
ジャンケンをポケコンがしてくれます。
「ジャンケンポン！」と出た後に何かキーを押すと
「グー」「チョキ」「パー」のいずれかが表示されます。
再度キーを押して「ジャンケンポン！」の表示に戻り、繰り返し表示を行います。
通常開発で考えられる乱数バージョンと、ポケコンの乱数では精度が良くないため、
キーを押すタイミングで決めるバージョンも用意しました。
どちらも見た目の動作に変化はありません。
10 PRINT "ｼﾞｬﾝｹﾝﾎﾟﾝ!"
20 IF INKEY$ <> "" GOTO 60
30 IF INKEY$ <> "" GOTO 70
40 IF INKEY$ <> "" GOTO 80
50 GOTO 20
60 PRINT "ｸﾞｰ":GOTO 90
70 PRINT "ﾁｮｷ":GOTO 90
80 PRINT "ﾊﾟｰ"
90 IF INKEY$ <> "" GOTO 90
100 IF INKEY$ = "" GOTO 100
110 IF INKEY$ <> "" GOTO 110
120 GOTO 10
15 パズル
PC-E200・G シリーズ 等
RUN すると 100 回動かします。
その後操作できるようになりますので、元の形に戻して下さい。
.. のところが空いているところです。ここを中心に
↓ ↑ ◀ ▶ （PC-G850 シリーズは ▼ ▲ ◀ ▶）および ２ ８ ４ ６ で操作します。
完成時は表示したままプログラムが終了するので（> が表示されています）
再度行う場合は RUN して下さい。
370・390 の U- INT (U/4)*4 は割り算のあまりを出していて、
PC-G850 シリーズだと U MOD 4 とできるのですが、
PC-E200・G801～G830 では MOD に対応していません。
100 CLS :RANDOMIZE :DIM D(16):S=100
110 FOR I=1 TO 16:D(I)=I:NEXT I
120 FOR L=1 TO S:GOSUB 310
130 R= RND 4
140 ON R GOSUB 360,370,380,390
150 IF C=U GOTO 130
160 T=D(C):D(C)=D(U):D(U)=T
170 NEXT L:GOSUB 310:S=0
180 LOCATE 13,0:PRINT "COUNT"
190 LOCATE 13,1:PRINT S:L=16
200 IF D(L)<>L GOTO 230
210 L=L-1:IF L>0 GOTO 200
220 LOCATE 12,1:END
230 I$= INKEY$
240 IF I$= CHR$ (4) OR I$="8" GOSUB 360
250 IF I$= CHR$ (14) OR I$="6" GOSUB 370
260 IF I$= CHR$ (5) OR I$="2" GOSUB 380
270 IF I$= CHR$ (15) OR I$="4" GOSUB 390
280 IF C=U GOTO 230
290 T=D(C):D(C)=D(U):D(U)=T
300 S=S+1:GOSUB 310:GOTO 180
310 LOCATE 0,0:FOR I=1 TO 16
320 IF D(I)=16 PRINT " ..";:U=I:GOTO 340
330 PRINT USING "###";D(I);
340 IF I=4 OR I=8 OR I=12 PRINT
350 NEXT :USING :RETURN
360 C=U+(U>4)*4:RETURN
370 C=U-(U- INT (U/4)*4>0):RETURN
380 C=U-(U<13)*4:RETURN
390 C=U+(U- INT (U/4)*4<>1):RETURN
カレンダー
PC-G850 シリーズ
年(西暦)・月を入力すると、その月のカレンダーを表示します。
通常は曜日を上部に表示しますが、
30日・31日が日・月曜になる場合は曜日がスクロールして消えます。
一番左が日曜日なので、まぁ～問題ないかと……
2009/05/02 変更
1月・2月の表示ができなかった不都合を修正しています。
（Thanks!! DELTAVOX さん）
100 DIM D(12)
110 INPUT "ﾈﾝ = ";Y
120 INPUT "ﾂｷ = ";M
130 FOR I=1 TO 12:READ D(I):NEXT I
140 IF Y MOD 4=0 AND (Y MOD 100<>0 OR Y MOD 400=0 ) LET D(2)=D(2)+1
150 IF M<3 LET Y=Y-1:M=M+12
160 O = INT (Y+ INT (Y/4)- INT (Y/100)+ INT (Y/400)+ INT ((13*M+8)/5)+1) MOD 7
170 IF M>12 LET M=M-12
180 CLS :LOCATE 0,0
190 PRINT "SunMonTueWedThuFriSat"
200 IF O>0 FOR I=1 TO O:PRINT " ";:NEXT I
210 I=O:FOR J=1 TO D(M)
220 PRINT USING "###";J;
230 I=I+1:IF I=7 PRINT :I=0
240 NEXT J
250 IF INKEY$ ="" GOTO 250
260 DATA 31,28,31,30,31,30
270 DATA 31,31,30,31,30,31
GIVEUP!
PC-G850 シリーズ
８２４６ または ▲ ▼ ◀ ▶ で移動し、長く生きて下さい。
上記のようになった後は何かのキーで再開。中断は ON(BREAK) キーです。
10 H=0:RANDOMIZE
20 CLS :LOCATE 17,0:PRINT "SCORE"
30 LOCATE 17,2:PRINT "HIGH"
40 LOCATE 18,3:PRINT H
50 LINE (0,0)-(99,47),S,B
60 X=50:Y=24:S=0:XX=0:YY=1
70 LOCATE 18,1:PRINT S:PSET (X,Y)
80 I$= INKEY$
90 IF I$="4" OR I$=CHR$(15) LET XX=-1:YY=0
100 IF I$="6" OR I$=CHR$(14) LET XX=1:YY=0
110 IF I$="8" OR I$=CHR$(4) LET XX=0:YY=-1
120 IF I$="2" OR I$=CHR$(5) LET XX=0:YY=1
130 X=X+XX:Y=Y+YY
140 CX= RND 100-1
150 CY= RND 48-1
160 IF CY-Y<-4 OR CY-Y>4 GOTO 190
170 IF CX-X<-4 OR CX-X>4 GOTO 190
180 GOTO 140
190 PSET (CX,CY)
200 IF POINT (X,Y)=1 GOTO 230
210 S=S+1
220 GOTO 70
230 FOR I=0 TO 99
240 XX= RND 100-1
250 YY= RND 48-1
260 LINE (X,Y)-(XX,YY)
270 NEXT I
280 IF S>H LET H=S
290 LOCATE 18,3:PRINT H
300 LOCATE 17,4:PRINT "PUSH"
310 LOCATE 17,5:PRINT "ANY KEY"
320 IF INKEY$ <>"" GOTO 320
330 IF INKEY$ ="" GOTO 330
340 GOTO 20
MSX 版、IchigoJam 版、PanCake+IchigoJam 版も存在します。
GIVE UP! | イチゴジャム レシピ - IchigoJam 版
GIVE UP! | イチゴジャム レシピ - PanCake+IchigoJam 版
15 パズル version 2
GPRINT を用いてパーツを大きく描いた 15 パズル です。
RUN すると WAIT 表示で
99 から 0 までカウントダウンしながらバラバラにしていきます。
COUNT 0 となったら操作できるようになりますので、
▲▼◀▶ または ８２４６ で空いているところを基準に操作していきます。
元の状態に戻したらプログラム終了です。再度行う場合は RUN して下さい。
100 RANDOMIZE :M=15:S=0:DIM P(15):CLS
110 FOR I=0 TO 14
120 LINE ((I MOD 4)*12+49, INT (I/4)*12+1)-((I MOD 4)*12+58, INT (I/4)*12+10),S,B
130 GCURSOR ((I MOD 4)*12+50, INT (I/4)*12+9)
140 P=I+1:GOSUB 490
150 P(I)=I+1:NEXT I
160 P(15)=16
170 LOCATE 17,2:PRINT "WAIT"
180 FOR I=99 TO 0 STEP -1
190 LOCATE 17,3:PRINT I;" ";
200 R= RND 4
210 ON R GOSUB 450,460,470,480
220 IF M=T GOTO 200
230 LINE ((T MOD 4)*12+49, INT (T/4)*12+1)-((T MOD 4)*12+58, INT (T/4)*12+10),R,BF
240 LINE ((M MOD 4)*12+49, INT (M/4)*12+1)-((M MOD 4)*12+58, INT (M/4)*12+10),S,B
250 GCURSOR ((M MOD 4)*12+50, INT (M/4)*12+9)
260 P=P(T):GOSUB 490
270 P(M)=P(T):P(T)=16:M=T:NEXT
280 LOCATE 17,2:PRINT "COUNT"
290 LOCATE 17,3:PRINT S:C=15
300 IF P(C)<>C+1 GOTO 330
310 C=C-1:IF C>0 GOTO 300
320 END
330 I$= INKEY$
340 IF I$="8" OR I$= CHR$ (4) GOSUB 450
350 IF I$="6" OR I$= CHR$ (14) GOSUB 460
360 IF I$="2" OR I$= CHR$ (5) GOSUB 470
370 IF I$="4" OR I$= CHR$ (15) GOSUB 480
380 IF M=T GOTO 330
390 LINE ((T MOD 4)*12+49, INT (T/4)*12+1)-((T MOD 4)*12+58, INT (T/4)*12+10),R,BF
400 LINE ((M MOD 4)*12+49, INT (M/4)*12+1)-((M MOD 4)*12+58, INT (M/4)*12+10),S,B
410 GCURSOR ((M MOD 4)*12+50, INT (M/4)*12+9)
420 P=P(T):GOSUB 490
430 P(M)=P(T):P(T)=16:M=T
440 S=S+1:GOTO 290
450 T=M+(M>3)*4:RETURN
460 T=M-(M MOD 4<3):RETURN
470 T=M-(M<12)*4:RETURN
480 T=M+(M MOD 4>0):RETURN
490 IF P=1 GPRINT "FFFFFFFFFFFF0000":RETURN
500 IF P=2 GPRINT "FFFFFF0404242020":RETURN
510 IF P=3 GPRINT "FFFFFF2424240000":RETURN
520 IF P=4 GPRINT "FFFFFFE0E0E70000":RETURN
530 IF P=5 GPRINT "FFFFFF2020240404":RETURN
540 IF P=6 GPRINT "FFFFFF0000240404":RETURN
550 IF P=7 GPRINT "FFFFFFFCFCFC0000":RETURN
560 IF P=8 GPRINT "FFFFFF0000240000":RETURN
570 IF P=9 GPRINT "FFFFFF2020240000":RETURN
580 IF P=10 GPRINT "0000FF00003C0000":RETURN
590 IF P=11 GPRINT "0000FFFFFFFF0000":RETURN
600 IF P=12 GPRINT "0000FF0404242020":RETURN
610 IF P=13 GPRINT "0000FF2424240000":RETURN
620 IF P=14 GPRINT "0000FFE0E0E70000":RETURN
630 IF P=15 GPRINT "0000FF2020240404":RETURN
640 GPRINT "0000000000000000":RETURN
箱入り娘
PC-G850 シリーズ
中央上の大きいパーツ（娘）を中央下まで移動します。
８２４６ または ▲ ▼ ◀ ▶ で移動し、
SPACE または ↵ で掴む・離すを切り替えます。
掴んでいる時は大きく、離してる時は小さく反転表示しています。
中央下へ移動できたらプログラム終了するので、再度行うなら RUN して下さい。
620～660 の DATA を変えるとパーツを変更できます。
（MSX-BASIC 版に同じなので、そちらを参照して下さい）
100 CLS :RESTORE :DIM P(19):PX=1:PY=4:C=0
110 LINE (52,0)-(91,47),S,BF
120 LINE (55,3)-(88,44),R,BF
130 LINE (64,45)-(79,47),R,BF
140 FOR I=0 TO 19:READ P(I)
150 GCURSOR ((I MOD 4)*8+56, INT (I/4)*8+11)
160 BL=P(I):GOSUB 520:NEXT I
170 GOSUB 500:MX=PX:MY=PY
180 I$= INKEY$
190 IF I$="8" OR I$= CHR$ (4) LET MY=PY-1
200 IF I$="2" OR I$= CHR$ (5) LET MY=PY+1
210 IF I$="6" OR I$= CHR$ (14) LET MX=PX+1
220 IF I$="4" OR I$= CHR$ (15) LET MX=PX-1
230 IF I$<>" " AND I$<> CHR$ (13) GOTO 270
240 IF INKEY$ <>"" GOTO 240
250 IF P(PX+PY*4)=16 GOTO 270
260 GOSUB 500:C=1-C:GOTO 170
270 IF MX=PX AND MY=PY GOTO 180
280 IF INKEY$ <>"" GOTO 280
290 IF MX<0 OR MX>3 LET MX=PX:GOTO 180
300 IF MY<0 OR MY>4 LET MY=PY:GOTO 180
310 GOSUB 500
320 IF C=0 LET PX=MX:PY=MY:GOTO 170
330 P=P(PX+PY*4):A= INT (P/4):B=P MOD 4
340 AX=A MOD 2:AY= INT (A/2)
350 BX=B MOD 2:BY= INT (B/2)
360 FOR YY=0 TO AY:FOR XX=0 TO AX
370 P(PX-BX+XX+(PY-BY+YY)*4)=16
380 GCURSOR ((PX-BX+XX)*8+56,(PY-BY+YY)*8+11)
390 BL=16:GOSUB 520:NEXT XX:NEXT YY
400 CH=1:FOR YY=0 TO AY:FOR XX=0 TO AX
410 IF MX-BX+XX+(MY-BY+YY)*4<0 OR MX-BX+XX+(MY-BY+YY)*4>19 LET CH=0:GOTO 430
420 IF P(MX-BX+XX+(MY-BY+YY)*4)<16 LET CH=0
430 NEXT XX:NEXT YY
440 IF CH=1 LET PX=MX:PY=MY
450 FOR YY=0 TO AY:FOR XX=0 TO AX
460 P(PX-BX+XX+(PY-BY+YY)*4)=P+XX-BX+(YY-BY)*2
470 GCURSOR ((PX-BX+XX)*8+56, INT (PY-BY+YY)*8+11)
480 BL=P+XX-BX+(YY-BY)*2:GOSUB 520:NEXT XX:NEXT YY
490 IF P(13)<>12 GOTO 170 ELSE END
500 IF C=1 LINE (PX*8+56,PY*8+4)-(PX*8+63,PY*8+11),X,BF:RETURN
510 LINE (PX*8+58,PY*8+6)-(PX*8+61,PY*8+9),X,BF:RETURN
520 IF BL=0 GPRINT "007E7E7E7E7E7E00":RETURN
530 IF BL=4 GPRINT "007E7E7E7E7E7E7E":RETURN
540 IF BL=5 GPRINT "7E7E7E7E7E7E7E00":RETURN
550 IF BL=8 GPRINT "00FEFEFEFEFEFE00":RETURN
560 IF BL=10 GPRINT "007F7F7F7F7F7F00":RETURN
570 IF BL=12 GPRINT "00FEFEFEFEFEFEFE":RETURN
580 IF BL=13 GPRINT "FEFEFEFEFEFEFE00":RETURN
590 IF BL=14 GPRINT "007F7F7F7F7F7F7F":RETURN
600 IF BL=15 GPRINT "7F7F7F7F7F7F7F00":RETURN
610 GPRINT "0000000000000000":RETURN
620 DATA 8,12,13, 8
630 DATA 10,14,15,10
640 DATA 8, 4, 5, 8
650 DATA 10, 0, 0,10
660 DATA 0,16,16, 0
MSX-BASIC 版、IchigoJam BASIC 版もあります。
箱入り娘 : MSX JAPAN▉ - MSX-BASIC 版
箱入り娘 | イチゴジャム レシピ - IchigoJam BASIC 版
サインカーブ
PC-G850 シリーズ
サインカーブを表示します。
PC-G シリーズでは三角暗数を計算する時に
60分法(DEG)・弧度法(RAD)・グラード法(GRAD) ３種類の計算ができるのですが、
ここでは電源を入れた状態の 60分法(DEG) を用います、（0°＝360°）
100 DEGREE
110 CLS
120 FOR X=0 TO 143 STEP 2
130 PSET (X,24)
140 NEXT X
150 O=24
160 FOR X=1 TO 143
170 Y= SIN (-X/144*360)*24+24
180 LINE (X-1,O)-(X,Y)
190 O=Y
200 NEXT X
PC-G815
PC-G815 のサイズ（144✕32）に変更しただけで、動作は同じです。
100 DEGREE
110 CLS
120 FOR X=0 TO 143 STEP 2
130 PSET (X,16)
140 NEXT X
150 O=16
160 FOR X=1 TO 143
170 Y= SIN (-X/144*360)*16+16
180 LINE (X-1,O)-(X,Y)
190 O=Y
200 NEXT X
z88dk を用いた C 言語版もあります。PC-G850 シリーズ以外でも動作します。
sin.c | GitHub Gist - z88dk C 言語版
MSX・IchigoLatte JS+PanCake 版もあります。
サインカーブ | MSX JAPAN▉ - MSX 版
サインカーブ | イチゴジャム レシピ - IchigoLatte JS＋PanCake 版
POKE COM ロゴ
PC-G850 シリーズ（修正して PC-G815 でも動作可）
トップページで表示しているロゴを表示します。
GPRINT 版と PRINT→POINT→LINE 版を用意しました。
PRINT→POINT→LINE 版は おまけ も用意しました。
エミュレータ g800 は一部文字の形状がポケコン実機と異なります。
そのため GPRINT 版と他 2 種類で表示が若干異なります。
100 CLS
110 GCURSOR (0,7)
120 GPRINT "FFFFFF070707070707070707F8F8F8000000";:' P
130 GPRINT "F8F8F8070707070707070707F8F8F8000000";:' O
140 GPRINT "FFFFFF000000C0C0C0383838070707000000";:' K
150 GPRINT "FFFFFF070707070707070707070707000000";:' E
160 GPRINT "000000000000000000000000000000000000";:'
170 GPRINT "F8F8F8070707070707070707383838000000";:' C
180 GPRINT "F8F8F8070707070707070707F8F8F8000000";:' O
190 GPRINT "FFFFFF383838C0C0C0383838FFFFFF000000";:' M
200 GCURSOR (0,15)
210 GPRINT "FFFFFF0E0E0E0E0E0E0E0E0E010101000000";:' P
220 GPRINT "FFFFFF000000000000000000FFFFFF000000";:' O
230 GPRINT "FFFFFF0E0E0E717171808080000000000000";:' K
240 GPRINT "FFFFFF0E0E0E0E0E0E0E0E0E000000000000";:' E
250 GPRINT "000000000000000000000000000000000000";:'
260 GPRINT "FFFFFF000000000000000000808080000000";:' C
270 GPRINT "FFFFFF000000000000000000FFFFFF000000";:' O
280 GPRINT "FFFFFF0000000F0F0F000000FFFFFF000000";:' M
290 GCURSOR (0,23)
300 GPRINT "1F1F1F000000000000000000000000000000";:' P
310 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' O
320 GPRINT "1F1F1F0000000000000303031C1C1C000000";:' K
330 GPRINT "1F1F1F1C1C1C1C1C1C1C1C1C1C1C1C000000";:' E
340 GPRINT "000000000000000000000000000000000000";:'
350 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' C
360 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' O
370 GPRINT "1F1F1F0000000000000000001F1F1F000000";:' M
380 LOCATE 0,3
390 PRINT "POCKET COMPUTER"
400 PRINT " INFORMATION SITE";
PC-G815 では最後の 2 行を削除して POKE COM のみにして表示できます。
Nyan Cat
PC-G850 シリーズ
YouTube で人気となった Nyan Cat を BASIC だけで行ってみました。
中央にしかでませんが、メモリ結構使ってます。
他のプログラムに比べて圧倒的に長いです。
手入力はおすすめしません。転送も少し時間を要します。
MSX 版で作ったものを白黒変換し調整しています。
IchigoJam（IchigoJam BASIC）版もできました。