BASIC プログラム
USB ケーブルやシリアルケーブルでパソコンと接続するのが便利です。
Windows では「PC-G リンク」を用いるのが普通です。
配布サイトがいくつかあります。
Mac では「PCG-LinkMac」等を使用できます。
ポケコン側は TEXT EDITOR より Sio - Load とするとパソコンから読み込みます。
読み込んだ後は Basic<text で BASIC の中間コードに変換して下さい。
エミュレータ g800 で動作させる簡単な方法は
ダウンロードしたファイル（GitHub Gist による表示ではなく
「ダウンロード」リンクから）
ドラック＆ドロップで g800 表示画面へ持っていくだけです。
その後 RUN ですぐに実行できます。
テスト版の互換 BASIC インタープリタで全プログラム正常動作を確認できています。
手入力したい場合は BASIC キーを押してモードを切り替えます。
PROGRAM MODE で入れた後、RUN MODE にして RUN で実行します。
GitHub Gist を用いて公開しているコードには MIT ライセンス の明示を行っています。
個人的に使用する場合、頭の ' は入力しなくても動作に影響はありませんが、
配布などを行う場合はライセンス上含める必要があります。
ジャンケンポン！
PC-E200・G シリーズ 等 / BASIC
ジャンケンをポケコンがしてくれます。
「ジャンケンポン！」と出た後に何かキーを押すと
「グー」「チョキ」「パー」のいずれかが表示されます。
再度キーを押して「ジャンケンポン！」の表示に戻り、繰り返し表示を行います。
通常開発で考えられる乱数バージョンと、ポケコンの乱数では精度が良くないため、
キーを押すタイミングで決めるバージョンも用意しました。
どちらも見た目の動作に変化はありません。
IchigoJam BASIC 版もあります。
10 PRINT "ｼﾞｬﾝｹﾝﾎﾟﾝ!"
20 IF INKEY$ <> "" GOTO 60
30 IF INKEY$ <> "" GOTO 70
40 IF INKEY$ <> "" GOTO 80
50 GOTO 20
60 PRINT "ｸﾞｰ":GOTO 90
70 PRINT "ﾁｮｷ":GOTO 90
80 PRINT "ﾊﾟｰ"
90 IF INKEY$ <> "" GOTO 90
100 IF INKEY$ = "" GOTO 100
110 IF INKEY$ <> "" GOTO 110
120 GOTO 10
カレンダー
PC-G850 シリーズ / BASIC
年・月を入力すると、その月のカレンダーを表示します。
通常は曜日を上部に表示しますが、
30日・31日が日・月曜になる場合は曜日がスクロールして消えます。
一番左が日曜日なので、まぁ～問題ないかと……
2009/05/02 変更
1月・2月の表示ができなかった不都合を修正しています。
（Thanks!! DELTAVOX さん）
IchigoJam BASIC 版も存在します。
100 DIM D(12)
110 INPUT "ﾈﾝ = ";Y
120 INPUT "ﾂｷ = ";M
130 FOR I=1 TO 12:READ D(I):NEXT I
140 IF Y MOD 4=0 AND (Y MOD 100<>0 OR Y MOD 400=0 ) LET D(2)=D(2)+1
150 IF M<3 LET Y=Y-1:M=M+12
160 O = INT (Y+ INT (Y/4)- INT (Y/100)+ INT (Y/400)+ INT ((13*M+8)/5)+1) MOD 7
170 IF M>12 LET M=M-12
180 CLS :LOCATE 0,0
190 PRINT "SunMonTueWedThuFriSat"
200 IF O>0 FOR I=1 TO O:PRINT " ";:NEXT I
210 I=O:FOR J=1 TO D(M)
220 PRINT USING "###";J;
230 I=I+1:IF I=7 PRINT :I=0
240 NEXT J
250 IF INKEY$ ="" GOTO 250
260 DATA 31,28,31,30,31,30
270 DATA 31,31,30,31,30,31
GIVEUP!
PC-G850 シリーズ / BASIC
[8][2][4][6] または カーソルキー で移動し、長く生きて下さい。
上記のようになった後は何かのキーで再開。中断は [ON](BREAK) キーです。
MSX 版、IchigoJam 版、PanCake+IchigoJam 版も存在します。
GIVE UP! | イチゴジャム レシピ - IchigoJam 版
GIVE UP! | イチゴジャム レシピ - PanCake+IchigoJam 版
10 H=0:RANDOMIZE
20 CLS :LOCATE 17,0:PRINT "SCORE"
30 LOCATE 17,2:PRINT "HIGH"
40 LOCATE 18,3:PRINT H
50 LINE (0,0)-(99,47),S,B
60 X=50:Y=24:S=0:XX=0:YY=1
70 LOCATE 18,1:PRINT S:PSET (X,Y)
80 I$= INKEY$
90 IF I$="4" OR I$=CHR$(15) LET XX=-1:YY=0
100 IF I$="6" OR I$=CHR$(14) LET XX=1:YY=0
110 IF I$="8" OR I$=CHR$(4) LET XX=0:YY=-1
120 IF I$="2" OR I$=CHR$(5) LET XX=0:YY=1
130 X=X+XX:Y=Y+YY
140 CX= RND 100-1
150 CY= RND 48-1
160 IF CY-Y<-4 OR CY-Y>4 GOTO 190
170 IF CX-X<-4 OR CX-X>4 GOTO 190
180 GOTO 140
190 PSET (CX,CY)
200 IF POINT (X,Y)=1 GOTO 230
210 S=S+1
220 GOTO 70
230 FOR I=0 TO 99
240 XX= RND 100-1
250 YY= RND 48-1
260 LINE (X,Y)-(XX,YY)
270 NEXT I
280 IF S>H LET H=S
290 LOCATE 18,3:PRINT H
300 LOCATE 17,4:PRINT "PUSH"
310 LOCATE 17,5:PRINT "ANY KEY"
320 IF INKEY$ <>"" GOTO 320
330 IF INKEY$ ="" GOTO 330
340 GOTO 20
サインカーブ
PC-G850 シリーズ / BASIC
サインカーブを表示します。
PC-G シリーズでは三角暗数を計算する時に
60分法(DEG)・弧度法(RAD)・グラード法(GRAD) ３種類の計算ができるのですが、
ここでは電源を入れた状態の 60分法(DEG) を用います、（0°＝360°）
z88dk を用いた C 言語版もあります。PC-G850 シリーズ以外でも動作します。
sin.c | GitHub Gist - z88dk C 言語版
MSX・IchigoLatte JS+PanCake 版もあります。
サインカーブ | MSX JAPAN▉ - MSX 版
サインカーブ | イチゴジャム レシピ - IchigoLatte JS＋PanCake 版
100 CLS
110 FOR X=0 TO 143 STEP 2
120 PSET (X,24)
130 NEXT X
140 O=24
150 FOR X=1 TO 143
160 Y= SIN (-X/144*360)*24+24
170 LINE (X-1,O)-(X,Y)
180 O=Y
190 NEXT X
風船
PC-G850 シリーズ / BASIC
風船を飛ばします。
GPRINT で風船を描き、CALL &HBFEB で 1 行上にスクロールします。
ただ、スクロール後に下で一瞬表示されてしまうので、
スクロール直前で消しています。（160 の空白は 24 文字＝1 行分 です）
PC-G850 シリーズではテキストとグラフィックが同じ画面で線画されるので、
この方法で実現できます。ただし LINE～,R,BF よりもテキストの方が速いです。
PC-G850 シリーズは Z80 を採用している中では新しい機種である事もあり、
GPRINT であれば、BASIC でもけっこうはやく、WAIT を入れている程です。
z88dk を用いた C 言語版もあります。PC-G850 シリーズ以外でも動作します。
balloons.c | GitHub Gist - z88dk C 言語版
MSX・IchigoJam・IchigoLatte・IchigonQuest 版もあります。
風船 | MSX JAPAN▉ - MSX 版
風船 | イチゴジャム レシピ - IchigoJam BASIC 版
風船 version 2 | イチゴジャム レシピ - IchigoLatte BASIC 版
風船 | イチゴジャム レシピ - IchigoLatte JavaScript 版
風船 | イチゴジャム レシピ - IchigoJLatte Ruby 版
風船 | イチゴジャム レシピ - IchigoJLatte Forth 版
風船 | イチゴジャム レシピ - IchigonQuest 版
100 CLS
110 X= RND (137)
120 GCURSOR (X,47)
130 GPRINT "1C3E7FFF7D3A1C"
140 WAIT 3
150 LOCATE 0,0
160 PRINT " "
170 CALL &HBFEB
180 GCURSOR (X,47)
190 GPRINT "0000009966"
200 GOTO 110
160 PRINT " " の "" 内は空白 24 文字です。（1 行の文字数）
170 CALL &HBFEB は次でも同じ動作になります。
170 LOCATE 0,5:PRINT:PRINT
POKE COM ロゴ
PC-G850 シリーズ / BASIC
トップページで表示しているロゴを表示します。
GPRINT 版と PRINT→POINT→LINE 版を用意しました。
PRINT→POINT→LINE 版は おまけ も用意しました。
エミュレータ g800 は一部文字の形状がポケコン実機と異なります。
そのため GPRINT 版と他 2 種類で表示が若干異なります。
100 CLS
110 GCURSOR (0,7)
120 GPRINT "FFFFFF070707070707070707F8F8F8000000";:' P
130 GPRINT "F8F8F8070707070707070707F8F8F8000000";:' O
140 GPRINT "FFFFFF000000C0C0C0383838070707000000";:' K
150 GPRINT "FFFFFF070707070707070707070707000000";:' E
160 GPRINT "000000000000000000000000000000000000";:'
170 GPRINT "F8F8F8070707070707070707383838000000";:' C
180 GPRINT "F8F8F8070707070707070707F8F8F8000000";:' O
190 GPRINT "FFFFFF383838C0C0C0383838FFFFFF000000";:' M
200 GCURSOR (0,15)
210 GPRINT "FFFFFF0E0E0E0E0E0E0E0E0E010101000000";:' P
220 GPRINT "FFFFFF000000000000000000FFFFFF000000";:' O
230 GPRINT "FFFFFF0E0E0E717171808080000000000000";:' K
240 GPRINT "FFFFFF0E0E0E0E0E0E0E0E0E000000000000";:' E
250 GPRINT "000000000000000000000000000000000000";:'
260 GPRINT "FFFFFF000000000000000000808080000000";:' C
270 GPRINT "FFFFFF000000000000000000FFFFFF000000";:' O
280 GPRINT "FFFFFF0000000F0F0F000000FFFFFF000000";:' M
290 GCURSOR (0,23)
300 GPRINT "1F1F1F000000000000000000000000000000";:' P
310 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' O
320 GPRINT "1F1F1F0000000000000303031C1C1C000000";:' K
330 GPRINT "1F1F1F1C1C1C1C1C1C1C1C1C1C1C1C000000";:' E
340 GPRINT "000000000000000000000000000000000000";:'
350 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' C
360 GPRINT "0303031C1C1C1C1C1C1C1C1C030303000000";:' O
370 GPRINT "1F1F1F0000000000000000001F1F1F000000";:' M
380 LOCATE 0,3
390 PRINT "POCKET COMPUTER"
400 PRINT " INFORMATION SITE";
NYAN CAT
PC-G850 シリーズ / BASIC
YouTube で人気となった NYAN CAT を BASIC だけで行ってみました。
音はでませんし、白黒ですし、実機では残像で、ハッキリ見えませんが……
MSX 版で作ったものを白黒変換し調整しています。
IchigoJam（IchigoJam BASIC）版もできました。
中央にしかでませんが、メモリ結構使ってます。
他のプログラムに比べて圧倒的に長いです。
手入力はおすすめしません。転送も少し時間を要します。